Menu contextuel windows 10 ajouter la date du jour à un fichier

Commentaire(s)

Ce petit script vbs de ma création, permet en faisant un clic droit sur un fichier (windows 10 ou 11) de le renommer en ajoutant la date du jour. Pratique et rapide.

Pas la peine de faire renommer le fichier et ensuite d'ajouter la date du jour manuellement.
Un clic droit sur le fichier > clic Ajouter la date du jour... et voilà, c'est fait...

Testé sur Windows 10 & 11.

Le script vbs

' Ce petit script vbscript permet lors d'un clic droit sur un fichier windows 10 ou 11, de lui ajouter la date du jour
' date au format jj-mm-aaaa
' exemple		: toto.zip -> toto-01-01-2024.zip
' auteur		: nonoweb
' site web		: https://www.nonoweb.net/
' création		: 12/08/2025
' modification	: 25/09/2025
option explicit
dim nbArgs, fso, fichier, path, fichier_date, pos, fichier_ext, fichier_name, test
dim laDate, jour, mois
nbArgs = WScript.Arguments.Count
if nbArgs = 1 then
	Set fso = WScript.CreateObject("Scripting.FileSystemObject")
	fichier = fso.GetFileName(WScript.Arguments(0))
	pos = InStrRev(fichier, ".")
	fichier_name = Left(fichier, pos-1)
	fichier_ext = Mid(fichier, pos+1)
	path = fso.GetParentFolderName(WScript.Arguments(0)) & "\"
	' Date
	jour = Day(Now)
	mois = Month(Now)
	if len(jour) = 1 then jour = "0" & jour
	if len(mois) = 1 then mois = "0" & mois
	laDate =  jour & "-" & mois & "-" & Year(Now)
	' on regarde si on a pas déjà ajouté la date au fichier
	test = InStr(fichier_name, "-" & laDate)
	' si test différent 0, on a déjà ajouté la date.
	' -----
	if test <> 0 then
		MsgBox fichier & " : La date du jour a déjà été ajoutée.",vbExclamation,"Ajout de la date du jour"
	else
		fichier_date = fichier_name & "-" & laDate & "." & fichier_ext
		fso.MoveFile path & fichier, path & fichier_date
		MsgBox fichier_date & " : Ajout de la date du jour effectuée.",vbInformation,"Ajout de la date du jour"
	end if
else
	MsgBox "Ce script doit-être exécuté à partir du menu contextuel d'un fichier.",vbExclamation,"Ajout de la date du jour"
end if
Set fso = Nothing

Les fichiers reg

Inclure la fonction dans le menu contextuel des fichiers

Windows Registry Editor Version 5.00

[HKEY_CLASSES_ROOT\*\shell\addDate]
@="Ajouter la date du jour"
"icon"="%SystemRoot%\\system32\\shell32.dll,249"

[HKEY_CLASSES_ROOT\*\shell\addDate\command]
"DelegateExecute"=""
@="wscript.exe D:\\AppData\\Programmes\\addDate\\addDate.vbs \"%1\""

Changer la ligne @="wscript.exe D:\\AppData\\Programmes\\addDate\\addDate.vbs \"%1\"" suivant l'emplacement de addDate.vbs sur le disque dur.

Retirer la fonction du menu contextuel

Windows Registry Editor Version 5.00

[-HKEY_CLASSES_ROOT\*\shell\addDate]

Le résultat en images

Ajouter date du jour

Ajouter date du jour

Téléchargement

addDate.zip (l'archive contient ces 3 fichiers : addDate.vbs, addDate-add.reg, addDate-remove.reg)

Source : http://www.nonoweb.net/menu-contextuel-windows-10-ajouter-la-date-du-jour-a-un-fichier

Laisser un commentaire (Seuls le nom et le commentaire sont requis).
Les commentaires sont modérés avant publication.

 
Sélection smileys